Working with Weeks in Power BI with European Calendar

If you are using Power BI in Europe, you have to keep in mind that the functions are not always returning European values. Apparently weeks differ in different continents. The difference mainly resides in the different day to start the week and the start date of weeks. Pay attention to the comments in the below code. They explain how to set the correct time for European Calenders. There might be differences  within europe as well but this works for the Netherlands. 

+Date_Incidents_creationDate = 
VAR MinYear = YEAR ( MIN ( Incidents[creationDateDate] ) )
VAR MaxYear = YEAR ( MAX ( Incidents[creationDateDate] ) )
RETURN
ADDCOLUMNS (
    FILTER (
        CALENDARAUTO( ),
        AND ( YEAR ( [Date] ) >= MinYear, YEAR ( [Date] ) <= MaxYear )
    ),
    "Year", YEAR ( [Date] ),
    "Quarter", "Q" & TRUNC ( ( MONTH ( [Date] ) - 1 ) / 3 ) + 1,
    "Month Name", FORMAT ( [Date], "mmmm" ),
    "Month Number", MONTH ( [Date] ),
    "Weekday", FORMAT ( [Date], "dddd" ),
    "Weekday number", WEEKDAY( [Date],2 ),                      // ,2 starts weekday on monday
    "Week", WEEKNUM( [Date],21 ),                               // 21 is for european calenders
    "Week Relative Filter", DATEDIFF(TODAY(),[Date]-1,WEEK),    // -1 to simulate start on monday
    "Week Start Date" , [Date] - WEEKDAY([Date],2) + 1,         // ,2 starts weekday on monday
    "Week End Date" , [Date] - WEEKDAY([Date],2) + 7,           // ,2 starts weekday on monday
    "Day", FORMAT ( [Date], "DD" ),
    "Days in Month", DAY(EOMONTH([Date],0)),
    "Sort", FORMAT ( [Date], "YYYYMM" )
)